{
  description = "SeaCogs Nix Flake";
  inputs.nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0.1.*.tar.gz";

  outputs =
    { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forEachSupportedSystem =
        f:
        nixpkgs.lib.genAttrs supportedSystems (
          system:
          f {
            pkgs = import nixpkgs { inherit system; };
          }
        );
    in
    {
      devShells = forEachSupportedSystem (
        { pkgs }:
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              python311
              uv
              forgejo-runner
              # Red-DiscordBot dependencies
              git
              libsodium
              libffi
              libaio
              jdk17
              # Material for MkDocs dependencies
              cairo
              pngquant
            ];
            shellHook = # bash
              ''
                export UV_PYTHON_PREFERENCE=only-system
                export UV_PYTHON_DOWNLOADS=never
                uv sync --all-groups
                alias uvr="uv run"
                source ./.venv/bin/activate
                export PYTHONPATH=`pwd`/.venv/${pkgs.python311.sitePackages}/:$PYTHONPATH
              '';
          };
        }
      );
    };
}